#! /bin/csh -f

if ($#argv < 1) then
    cat << BLAH
Use: "$0 <machine> [<make-options>] <targets>"
     <machine>      = 'vax sun3.{68881,soft} sun4.O[1-4] mips.O[1-4]'
     <make-options> = -i, -k, -n etc.
     <targets>      = help
BLAH
    exit(1)
endif

switch ($argv[1])	# C'est brutal, mais ca marche
    case *.O1:
	set OPT=-O1
	breaksw
    case *.O2:
	set OPT=-O2
	breaksw
    case *.O3:
	set OPT=-O3
	breaksw
    case *.O4:
	set OPT=-O4
	breaksw
    default:
	set OPT=-O
	breaksw
endsw

set CC=cc	# C compiler
set FC=f77	# FORTRAN compiler
set NOP=	# C/FORTRAN compiler flag for "don't optimize"
set REL=-c	# C/FORTRAN compiler flag for "just build object, not a.out"
set O=.o	# Suffix for object files

switch ($argv[1])
    case vax:
	set FC = "f77 -q"
	breaksw
    case sun3.soft:
	set CC="cc  -fsoft"
	set FC="f77 -fsoft"
	breaksw
    case sun3.68881:
	set CC="cc  -f68881"
	set FC="f77 -f68881"
	breaksw
    case sun4.O[1-4]:
	set NOP=-O0
	breaksw
    case mips.O[34]:
	# -O3 and -O4 build .u files, not .o
	set O=.u
	set REL=-j
	# fall into...
    case mips.O[12]:
	set CC="cc -Olimit 1060"
	set NOP=-O0
	breaksw
    default:
	breaksw
endsw

make -f makefile.bench CC="$CC" FC="$FC" NOP="$NOP"\
	OPT="$OPT" O="$O" REL="$REL" $argv[2-]:q